Container login script

The container login script should contain as much information as possible that applies to all users. An example is shown in the following list:

• MAP DISPLAY OFF

  Prevents MAP commands from displaying on the screen as they are assigned.

• MAP ERRORS OFF

  Prevents mapping errors from displaying on the screen.

• MAP 1:=SYS:

  Maps the first drive to volume SYS:.

• MAP 1:=SYS:%LOGIN_NAME

  Maps the first drive to the user's home directory if LOGIN_NAME is the same as the user's home directory. If the user has no home directory, the first drive is still mapped to SYS:.

• IF "%1"="ADMIN" THEN MAP 1:=SYS:SYSTEM

  If the login name is ADMIN, the first drive is mapped to SYS:SYSTEM instead of the user's home directory.

• IF OS2="OS2" THEN
  MAP P:=SYS:PUBLIC
  ELSE
  MAP INS S1:=SYS:PUBLIC
  MAP INS S2:=SYS:PUBLIC\%MACHINE\%OS\
  %OS_VERSION
  END

  If the user logs in from an OS/2 workstation, drive P: is mapped to SYS:PUBLIC.

  This mapping is used by OS/2 workstations, as explained in NetWare Client for OS/2 User Guide.

  If the user is not using an OS/2 workstation, the first search drive is mapped to SYS:PUBLIC where DOS-based NetWare utilities are stored. The second search drive is mapped to the directory where DOS is stored.

  If all workstations use DOS, you can use the following commands instead of the IF...THEN command:

  MAP INS S1:=SYS:PUBLICMAP INS S2:=SYS:PUBLIC\ %MACHINE\%OS\%OS_VERSION
  IF MEMBER OF "WIN31" THEN
  MAP INS *2:=SYS:USERS\%LOGIN_NAME\WIN31
  MAP INS S16:=SYS:APPS\WINAPPS\WIN31\
  SET TEMP ="P:\USERS\%LOGIN_NAME\
  WIN31\
  TEMP"
  END
  

  If the user who logs in is a member of the Group object WIN31, the next available drive is mapped to that user's Windows directory. Then the next available search drive is mapped to the Windows directory for the WIN31 group. Finally, the Windows TEMP directory is set to a subdirectory of the user's Windows directory.

• MAP INS S16:=VOL1:APPL\WP

  Maps the next available search drive to the directory that contains WordPerfect.

• MAP INS S16:=VOL1:APPL\LOTUS

  Maps the next available search drive to the directory that contains Lotus.

• MAP INS S16:=SYS:EMAIL

  Maps the next available search drive to the EMAIL directory.

• IF MEMBER OF "MANAGERS" THEN
  MAP 3:=VOL1:PROJECTS\REPORTS
  END

  If the user belongs to the Group object MANAGERS, the login script maps the third network drive to the REPORTS directory.

• IF MEMBER OF "TESTERS" THEN
  MAP 4:=INPUT:STATUS\UPDATES
  END

  If the user belongs to the Group object TESTERS, the login script maps the fourth network drive to the UPDATES directory.

• COMSPEC=S2:COMMAND.COM

  Sets COMSPEC to the DOS command processor, located in the DOS directory (in the second search drive).

• SET PROMPT="$P$G"

  Sets the prompt to display the user's current directory path followed by the ">" symbol.

• MAP DISPLAY ON

  Allows MAP commands to display.

• MAP

  Displays a list of all drive mappings.

• WRITE

  Displays a blank line between the list of mappings and following lines.

• WRITE "Good %GREETING_TIME, %LAST_NAME."

  Displays a greeting to the user. Example: ``Good morning, SMITH.''.

• WRITE "Your password expires in %PASSWORD_EXPIRES days."

  Displays a message indicating the number of days before the user's password expires.

• FIRE 3

  Makes the phaser sound occur three times to tell the user that the login process is complete.